Creating MongoDB clusters

If you don't have the Yandex.Cloud command line interface yet, install and initialize it.

The folder specified in the CLI profile is used by default. You can specify a different folder using the --folder-name or --folder-id parameter.

To create a cluster:

1. Check whether the folder has any subnets for the cluster hosts:

   $ yc vpc subnet list
   

   If there are no subnets in the folder, create the necessary subnets in VPC.

2. View a description of the CLI's create cluster command:

   $ yc managed-mongodb cluster create --help
   

3. Specify the cluster parameters in the create command (the example shows only mandatory flags):

   $ yc managed-mongodb cluster create \
      --cluster-name <cluster name>
      --environment=<prestable or production> \
      --network-name <network name> \
      --host zone-id=<availability zone>,subnet-id=<subnet ID> \
      --mongod-resource-preset <host class> \
      --user name=<user name>, password=<user password> \
      --database name=<database name>,owner=<database owner name> \
      --mongod-disk-type <network-hdd | network-ssd | local-ssd> \
      --mongod-disk-size <storage size in GB>
   

   The subnet ID subnet-id should be specified if the selected availability zone contains two or more subnets.

With Terraform, you can quickly create a cloud infrastructure in Yandex.Cloud. The infrastructure components are identified through configuration files that specify the required cloud resources and their parameters.

If you don't have Terraform yet, install it and configure the provider.

To create a cluster:

1. In the configuration file, describe the parameters of resources that you want to create:

   • Database cluster: Description of the cluster and its hosts.
   • Network: Description of the cloud network where the cluster will be located. If you already have a suitable network, you don't need to describe it again.
   • Subnets: Description of the subnets to connect the cluster hosts to. If you already have suitable subnets, you don't need to describe them again.

   Example configuration file structure:

   resource "yandex_mdb_mongodb_cluster" "<cluster name>" {
     name        = "<cluster name>"
     environment = "<PRESTABLE or PRODUCTION>"
     network_id  = "<network ID>"
   
     cluster_config {
       version = "MongoDB version: 3.6, 4.0, or 4.2"
     }
   
     database {
       name = "<DB name>"
     }
   
     user {
       name     = "<username>"
       password = "<user password>"
       permission {
         database_name = "<database name>"
       }
     }
   
     resources {
       resource_preset_id = "<host class>"
       disk_type_id       = "<storage type>"    
       disk_size          = "<storage size in GB>"
     }
   
     host {
       zone_id   = "<availability zone>"
       subnet_id = "<subnet ID>"
     }
   }
   
   resource "yandex_vpc_network" "<network name>" { name = "<network name>" }
   
   resource "yandex_vpc_subnet" "<subnet name>" {
     name           = "<subnet name>" 
     zone           = "<availability zone>"
     network_id     = "<network ID>"
     v4_cidr_blocks = ["<range>"]
   }
   

   For more information about resources that you can create using Terraform, see the provider's documentation.

2. Make sure that the configuration files are correct.

   1. In the command line, go to the folder where you created the configuration file.

   2. Run the check using the command:

      terraform plan
      

   If the configuration is described correctly, the terminal displays a list of created resources and their parameters. If there are errors in the configuration, Terraform points them out. This is a test step. No resources are created.

3. Create a cluster.

   1. If the configuration doesn't contain any errors, run the command:

      terraform apply
      

   2. Confirm that you want to create the resources.

   After this, all the necessary resources will be created in the specified folder and the IP addresses of the VMs will be displayed in the terminal. You can check resource availability and their settings in management console.

Let's say we need to create a MongoDB cluster and a network for it with the following characteristics:

• Named mymg.
• Version 4.2.
• In the PRODUCTION environment.
• In the cloud with ID b1gq90dgh25bebiu75o.
• In a folder named myfolder.
• In a new network named mynet.
• With 1 s2.micro class host in the new mysubnet subnet and ru-central1-c availability zone. The mysubnet subnet will have the range 10.5.0.0/24.
• With 20 GB fast network storage (network-ssd).
• With one user, user1, with the password user1user1.
• With one database, db1.

The configuration file for the cluster looks like this:

provider "yandex" {
  token     = "<OAuth or static key of service account>"
  cloud_id  = "b1gq90dgh25bebiu75o"
  folder_id = "${data.yandex_resourcemanager_folder.myfolder.id}"
  zone      = "ru-central1-c"
}

resource "yandex_mdb_mongodb_cluster" "mymg" {
  name        = "mymg"
  environment = "PRODUCTION"
  network_id  = "${yandex_vpc_network.mynet.id}"

  cluster_config {
    version = "4.2"
  }

  database {
    name = "db1"
  }

  user {
    name     = "user1"
    password = "user1user1"
    permission {
      database_name = "db1"
    }
  }

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"    
    disk_size          = 20
  }

  host {
    zone_id   = "ru-central1-c"
    subnet_id = "${yandex_vpc_subnet.mysubnet.id}"
  }
}

resource "yandex_vpc_network" "mynet" { name = "mynet" }

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-c"
  network_id     = "${yandex_vpc_network.mynet.id}"
  v4_cidr_blocks = ["10.5.0.0/24"]
}